scoreboard players add @s svm_ep.used_move 1
scoreboard players add @s svm_ep.mana_drain 1
scoreboard players remove @s[scores={svm_ep.mana_drain=2..}] svm_ep.mana 1
execute as @s[scores={svm_ep.mana_drain=2..}] run scoreboard players reset @s svm_ep.mana_drain

scoreboard players add @s svm_ep.p.fire_ability_06_delay 2
scoreboard players set @s[scores={svm_ep.p.fire_ability_06_delay=60..}] svm_ep.p.fire_ability_06_delay 60
scoreboard players add @s svm_ep.used_move 3
effect give @s minecraft:slowness 1 0 true
effect give @s minecraft:weakness 1 3 true
effect give @s minecraft:mining_fatigue 1 2 true

tag @s add executor
execute at @s anchored eyes positioned ^ ^ ^8 as @e[scores={svm_ep.projectile=-10..},distance=..12,sort=nearest] run function svm_ep:power/fire/blaze/burn_projectile
execute at @s anchored eyes positioned ^ ^ ^8 as @e[type=!#svm_ep:technical,distance=..12,tag=!executor,limit=1,sort=nearest] run function svm_ep:power/fire/blaze/burn_mob
execute at @s anchored eyes positioned ^ ^ ^8 run fill ~5 ~5 ~5 ~-5 ~-5 ~-5 fire[age=0] replace fire

execute at @s anchored eyes positioned ^ ^ ^4.5 run particle minecraft:flame ~ ~ ~ 2 2 2 0.15 10
execute at @s anchored eyes positioned ^ ^ ^4.5 run particle minecraft:dust{color:[18000000f,18000000f,0f],scale:2f} ~ ~0.1 ~ 2 2 2 0 1
execute at @s anchored eyes positioned ^ ^ ^4.5 run particle minecraft:dust{color:[18000000f,1f,0f],scale:2f} ~ ~0.1 ~ 2 2 2 0 3
execute at @s anchored eyes positioned ^ ^ ^4.5 run particle minecraft:dust{color:[18000000f,0.5f,0f],scale:2f} ~ ~0.1 ~ 2 2 2 0 5
execute at @s run playsound minecraft:block.fire.ambient master @a ~ ~ ~ 0.25 1

execute at @s run particle minecraft:dust{color:[18000000f,18000000f,0f],scale:2.5f} ~ ~0.1 ~ 0.2 0.2 0.2 0 1
execute at @s run particle minecraft:dust{color:[18000000f,1f,0f],scale:2.25f} ~ ~0.1 ~ 0.2 0.2 0.2 0 1
execute at @s run particle minecraft:dust{color:[18000000f,0.75f,0f],scale:2f} ~ ~0.05 ~ 0.3 0.1 0.3 0 2
execute at @s run particle minecraft:dust{color:[18000000f,0.5f,0f],scale:1.75f} ~ ~0.025 ~ 0.5 0.1 0.5 0 2
execute at @s run particle minecraft:dust{color:[18000000f,0.25f,0f],scale:1.5f} ~ ~0.025 ~ 0.8 0.1 0.8 0 4
execute at @s run particle minecraft:dust{color:[1f,0.25f,0f],scale:1.25f} ~ ~0.025 ~ 0.8 0.1 0.8 0 8



tag @s remove executor

execute unless predicate svm_ep:shift run scoreboard players reset @s svm_ep.using_move
scoreboard players reset @s[scores={svm_ep.using_move=..501}] svm_ep.using_move
scoreboard players reset @s[scores={svm_ep.mana=..1}] svm_ep.using_move