
execute at @s positioned ^ ^ ^1.35 if block ~ ~ ~ #svm_ep:no_physical_hitbox run tp @s ~ ~ ~
execute at @s positioned ^ ^ ^1.35 unless block ~ ~ ~ #svm_ep:no_physical_hitbox run scoreboard players reset @s svm_ep.using_move

execute at @s positioned ^ ^-2.3 ^-0.85 run function svm_ep:power/ice/slide/place
execute at @s positioned ^1.15 ^-2.3 ^-0.95 run function svm_ep:power/ice/slide/place
execute at @s positioned ^-1.15 ^-1.9 ^-0.95 run function svm_ep:power/ice/slide/place
execute at @s positioned ^ ^-1.3 ^-0.85 run function svm_ep:power/ice/slide/place
execute at @s positioned ^1.15 ^-1.3 ^-0.95 run function svm_ep:power/ice/slide/place
execute at @s positioned ^-1.15 ^-1.3 ^-0.95 run function svm_ep:power/ice/slide/place
execute at @s positioned ^0.75 ^-1.3 ^-1.1 run function svm_ep:power/ice/slide/place
execute at @s positioned ^-0.75 ^-1.3 ^-1.1 run function svm_ep:power/ice/slide/place

execute at @s anchored eyes positioned ^0.35 ^-0.3 ^0.7 run particle poof ~ ~.2 ~ ^ ^ ^-100000 .000015 0
execute at @s anchored eyes positioned ^-0.35 ^-0.3 ^0.7 run particle poof ~ ~.2 ~ ^ ^ ^-100000 .000015 0


effect give @s minecraft:slow_falling 1 0 true
scoreboard players set @s svm_ep.using_move 350

scoreboard players add @s svm_ep.p.ice_ability_04_delay 3
scoreboard players remove @s svm_ep.mana 2
execute if score @s svm_ep.p.ice_ability_04_delay matches 200.. run scoreboard players reset @s svm_ep.using_move
execute unless score @s svm_ep.mana matches 2.. run scoreboard players reset @s svm_ep.using_move
execute unless predicate svm_ep:shift run scoreboard players reset @s svm_ep.using_move
execute unless score @s svm_ep.using_move matches 1.. run scoreboard players set @s[scores={svm_ep.p.ice_ability_04_delay=140..}] svm_ep.p.ice_ability_04_delay 140
